Index: src/forwarding/forwarding-amd64-elf.S
==================================================================
--- src/forwarding/forwarding-amd64-elf.S
+++ src/forwarding/forwarding-amd64-elf.S
@@ -15,188 +15,190 @@
 
 #include "config.h"
 
 #include "platform.h"
 
+.intel_syntax noprefix
+
 .globl OFForward
 .globl OFForward_stret
 
 .section .text
 OFForward:
-	pushq	%rbp
-	movq	%rsp, %rbp
+	push	rbp
+	mov	rbp, rsp
 
 	/* Save all arguments */
-	subq	$0xC0, %rsp	/* 16-byte alignment */
-	movq	%rax, -0x8(%rbp)
-	movq	%rdi, -0x10(%rbp)
-	movq	%rsi, -0x18(%rbp)
-	movq	%rdx, -0x20(%rbp)
-	movq	%rcx, -0x28(%rbp)
-	movq	%r8, -0x30(%rbp)
-	movq	%r9, -0x38(%rbp)
-	movaps	%xmm0, -0x50(%rbp)
-	movaps	%xmm1, -0x60(%rbp)
-	movaps	%xmm2, -0x70(%rbp)
-	movaps	%xmm3, -0x80(%rbp)
-	movaps	%xmm4, -0x90(%rbp)
-	movaps	%xmm5, -0xA0(%rbp)
-	movaps	%xmm6, -0xB0(%rbp)
-	movaps	%xmm7, -0xC0(%rbp)
+	sub	rsp, 0xC0	/* 16-byte alignment */
+	mov	[rbp - 0x08], rax
+	mov	[rbp - 0x10], rdi
+	mov	[rbp - 0x18], rsi
+	mov	[rbp - 0x20], rdx
+	mov	[rbp - 0x28], rcx
+	mov	[rbp - 0x30], r8
+	mov	[rbp - 0x38], r9
+	movaps	[rbp - 0x50], xmm0
+	movaps	[rbp - 0x60], xmm1
+	movaps	[rbp - 0x70], xmm2
+	movaps	[rbp - 0x80], xmm3
+	movaps	[rbp - 0x90], xmm4
+	movaps	[rbp - 0xA0], xmm5
+	movaps	[rbp - 0xB0], xmm6
+	movaps	[rbp - 0xC0], xmm7
 
 	call	object_getClass@PLT
 
-	movq	%rax, %rdi
-	leaq	sel_forwardingTargetForSelector_(%rip), %rsi
+	mov	rdi, rax
+	lea	rsi, [rip + sel_forwardingTargetForSelector_]
 	call	class_respondsToSelector@PLT
 
-	testq	%rax, %rax
-	jz	0f
-
-	movq	-0x10(%rbp), %rdi
-	leaq	sel_forwardingTargetForSelector_(%rip), %rsi
-	call	objc_msg_lookup@PLT
-
-	movq	-0x10(%rbp), %rdi
-	leaq	sel_forwardingTargetForSelector_(%rip), %rsi
-	movq	-0x18(%rbp), %rdx
-	call	*%rax
-
-	testq	%rax, %rax
-	jz	0f
-	cmpq	-0x10(%rbp), %rax
-	je	0f
-
-	movq	%rax, -0x10(%rbp)
-
-	movq	%rax, %rdi
-	movq	-0x18(%rbp), %rsi
-	call	objc_msg_lookup@PLT
-	movq	%rax, %r11
+	test	rax, rax
+	jz	short 0f
+
+	mov	rdi, [rbp - 0x10]
+	lea	rsi, [rip + sel_forwardingTargetForSelector_]
+	call	objc_msg_lookup@PLT
+
+	mov	rdi, [rbp - 0x10]
+	lea	rsi, [rip + sel_forwardingTargetForSelector_]
+	mov	rdx, [rbp - 0x18]
+	call	rax
+
+	test	rax, rax
+	jz	short 0f
+	cmp	rax, [rbp - 0x10]
+	je	short 0f
+
+	mov	[rbp - 0x10], rax
+
+	mov	rdi, rax
+	mov	rsi, [rbp - 0x18]
+	call	objc_msg_lookup@PLT
+	mov	r11, rax
 
 	/* Restore all arguments */
-	movaps	-0xC0(%rbp), %xmm7
-	movaps	-0xB0(%rbp), %xmm6
-	movaps	-0xA0(%rbp), %xmm5
-	movaps	-0x90(%rbp), %xmm4
-	movaps	-0x80(%rbp), %xmm3
-	movaps	-0x70(%rbp), %xmm2
-	movaps	-0x60(%rbp), %xmm1
-	movaps	-0x50(%rbp), %xmm0
-	movq	-0x38(%rbp), %r9
-	movq	-0x30(%rbp), %r8
-	movq	-0x28(%rbp), %rcx
-	movq	-0x20(%rbp), %rdx
-	movq	-0x18(%rbp), %rsi
-	movq	-0x10(%rbp), %rdi
-	movq	-0x8(%rbp), %rax
-
-	movq	%rbp, %rsp
-	popq	%rbp
-
-	jmpq	*%r11
+	movaps	xmm7, [rbp - 0xC0]
+	movaps	xmm6, [rbp - 0xB0]
+	movaps	xmm5, [rbp - 0xA0]
+	movaps	xmm4, [rbp - 0x90]
+	movaps	xmm3, [rbp - 0x80]
+	movaps	xmm2, [rbp - 0x70]
+	movaps	xmm1, [rbp - 0x60]
+	movaps	xmm0, [rbp - 0x50]
+	mov	r9, [rbp - 0x38]
+	mov	r8, [rbp - 0x30]
+	mov	rcx, [rbp - 0x28]
+	mov	rdx, [rbp - 0x20]
+	mov	rsi, [rbp - 0x18]
+	mov	rdi, [rbp - 0x10]
+	mov	rax, [rbp - 0x08]
+
+	mov	rsp, rbp
+	pop	rbp
+
+	jmp	r11
 
 0:
-	movq	-0x10(%rbp), %rdi
-	movq	-0x18(%rbp), %rsi
+	mov	rdi, [rbp - 0x10]
+	mov	rsi, [rbp - 0x18]
 
-	movq	%rbp, %rsp
-	popq	%rbp
+	mov	rsp, rbp
+	pop	rbp
 
 	jmp	OFMethodNotFound@PLT
 .type OFForward, %function
 .size OFForward, .-OFForward
 
 OFForward_stret:
-	pushq	%rbp
-	movq	%rsp, %rbp
+	push	rbp
+	mov	rbp, rsp
 
 	/* Save all arguments */
-	subq	$0xC0, %rsp	/* 16-byte alignment */
-	movq	%rax, -0x8(%rbp)
-	movq	%rdi, -0x10(%rbp)
-	movq	%rsi, -0x18(%rbp)
-	movq	%rdx, -0x20(%rbp)
-	movq	%rcx, -0x28(%rbp)
-	movq	%r8, -0x30(%rbp)
-	movq	%r9, -0x38(%rbp)
-	movaps	%xmm0, -0x50(%rbp)
-	movaps	%xmm1, -0x60(%rbp)
-	movaps	%xmm2, -0x70(%rbp)
-	movaps	%xmm3, -0x80(%rbp)
-	movaps	%xmm4, -0x90(%rbp)
-	movaps	%xmm5, -0xA0(%rbp)
-	movaps	%xmm6, -0xB0(%rbp)
-	movaps	%xmm7, -0xC0(%rbp)
-
-	movq	%rsi, %rdi
+	sub	rsp, 0xC0	/* 16-byte alignment */
+	mov	[rbp - 0x08], rax
+	mov	[rbp - 0x10], rdi
+	mov	[rbp - 0x18], rsi
+	mov	[rbp - 0x20], rdx
+	mov	[rbp - 0x28], rcx
+	mov	[rbp - 0x30], r8
+	mov	[rbp - 0x38], r9
+	movaps	[rbp - 0x50], xmm0
+	movaps	[rbp - 0x60], xmm1
+	movaps	[rbp - 0x70], xmm2
+	movaps	[rbp - 0x80], xmm3
+	movaps	[rbp - 0x90], xmm4
+	movaps	[rbp - 0xA0], xmm5
+	movaps	[rbp - 0xB0], xmm6
+	movaps	[rbp - 0xC0], xmm7
+
+	mov	rdi, rsi
 	call	object_getClass@PLT
 
-	movq	%rax, %rdi
-	leaq	sel_forwardingTargetForSelector_(%rip), %rsi
+	mov	rdi, rax
+	lea	rsi, [rip + sel_forwardingTargetForSelector_]
 	call	class_respondsToSelector@PLT
 
-	testq	%rax, %rax
-	jz	0f
+	test	rax, rax
+	jz	short 0f
 
-	movq	-0x18(%rbp), %rdi
-	leaq	sel_forwardingTargetForSelector_(%rip), %rsi
+	mov	rdi, [rbp - 0x18]
+	lea	rsi, [rip + sel_forwardingTargetForSelector_]
 	call	objc_msg_lookup@PLT
 
-	movq	-0x18(%rbp), %rdi
-	leaq	sel_forwardingTargetForSelector_(%rip), %rsi
-	movq	-0x20(%rbp), %rdx
-	call	*%rax
-
-	testq	%rax, %rax
-	jz	0f
-	cmpq	-0x18(%rbp), %rax
-	je	0f
-
-	movq	%rax, -0x18(%rbp)
-
-	movq	%rax, %rdi
-	movq	-0x20(%rbp), %rsi
+	mov	rdi, [rbp - 0x18]
+	lea	rsi, [rip + sel_forwardingTargetForSelector_]
+	mov	rdx, [rbp - 0x20]
+	call	rax
+
+	test	rax, rax
+	jz	short 0f
+	cmp	rax, [rbp - 0x18]
+	je	short 0f
+
+	mov	[rbp - 0x18], rax
+
+	mov	rdi, rax
+	mov	rsi, [rbp - 0x20]
 	call	objc_msg_lookup_stret@PLT
-	movq	%rax, %r11
+	mov	r11, rax
 
 	/* Restore all arguments */
-	movaps	-0xC0(%rbp), %xmm7
-	movaps	-0xB0(%rbp), %xmm6
-	movaps	-0xA0(%rbp), %xmm5
-	movaps	-0x90(%rbp), %xmm4
-	movaps	-0x80(%rbp), %xmm3
-	movaps	-0x70(%rbp), %xmm2
-	movaps	-0x60(%rbp), %xmm1
-	movaps	-0x50(%rbp), %xmm0
-	movq	-0x38(%rbp), %r9
-	movq	-0x30(%rbp), %r8
-	movq	-0x28(%rbp), %rcx
-	movq	-0x20(%rbp), %rdx
-	movq	-0x18(%rbp), %rsi
-	movq	-0x10(%rbp), %rdi
-	movq	-0x8(%rbp), %rax
-
-	movq	%rbp, %rsp
-	popq	%rbp
-
-	jmpq	*%r11
+	movaps	xmm7, [rbp - 0xC0]
+	movaps	xmm6, [rbp - 0xB0]
+	movaps	xmm5, [rbp - 0xA0]
+	movaps	xmm4, [rbp - 0x90]
+	movaps	xmm3, [rbp - 0x80]
+	movaps	xmm2, [rbp - 0x70]
+	movaps	xmm1, [rbp - 0x60]
+	movaps	xmm0, [rbp - 0x50]
+	mov	r9, [rbp - 0x38]
+	mov	r8, [rbp - 0x30]
+	mov	rcx, [rbp - 0x28]
+	mov	rdx, [rbp - 0x20]
+	mov	rsi, [rbp - 0x18]
+	mov	rdi, [rbp - 0x10]
+	mov	rax, [rbp - 0x08]
+
+	mov	rsp, rbp
+	pop	rbp
+
+	jmp	r11
 
 0:
-	movq	-0x10(%rbp), %rdi
-	movq	-0x18(%rbp), %rsi
-	movq	-0x20(%rbp), %rdx
+	mov	rdi, [rbp - 0x10]
+	mov	rsi, [rbp - 0x18]
+	mov	rdx, [rbp - 0x20]
 
-	movq	%rbp, %rsp
-	popq	%rbp
+	mov	rsp, rbp
+	pop	rbp
 
 	jmp	OFMethodNotFound_stret@PLT
 .type OFForward_stret, %function
 .size OFForward_stret, .-OFForward_stret
 
 init:
-	leaq	module(%rip), %rdi
+	lea	rdi, [rip + module]
 	jmp	__objc_exec_class@PLT
 
 #ifdef OF_SOLARIS
 .section .init_array, "aw"
 #else

Index: src/runtime/lookup-asm/lookup-asm-amd64-elf.S
==================================================================
--- src/runtime/lookup-asm/lookup-asm-amd64-elf.S
+++ src/runtime/lookup-asm/lookup-asm-amd64-elf.S
@@ -15,69 +15,71 @@
 
 #include "config.h"
 
 #include "platform.h"
 
+.intel_syntax noprefix
+
 .globl objc_msg_lookup
 .globl objc_msg_lookup_stret
 .globl objc_msg_lookup_super
 .globl objc_msg_lookup_super_stret
 
 .section .text
 .macro GENERATE_LOOKUP name notFound
 \name:
-	testq	%rdi, %rdi
-	jz	returnNilMethod
-
-	testb	$1, %dil
-	jnz	.LtaggedPointer_\name
-
-	movq	(%rdi), %r8
-	movq	64(%r8), %r8
+	test	rdi, rdi
+	jz	short returnNilMethod
+
+	test	dil, 1
+	jnz	short .LtaggedPointer_\name
+
+	mov	r8, [rdi]
+	mov	r8, [r8 + 64]
 
 .Lmain_\name:
-	movq	(%rsi), %rax
-	movzbl	%ah, %ecx
-	movzbl	%al, %edx
+	mov	rax, [rsi]
+	movzx	ecx, ah
+	movzx	edx, al
 #ifdef OF_SELUID24
-	shrl	$16, %eax
+	shr	eax, 16
 
-	movq	(%r8,%rax,8), %r8
+	mov	r8, [r8 + 8 * rax]
 #endif
-	movq	(%r8,%rcx,8), %r8
-	movq	(%r8,%rdx,8), %rax
+	mov	r8, [r8 + 8 * rcx]
+	mov	rax, [r8 + 8 * rdx]
 
-	testq	%rax, %rax
-	jz	\notFound@PLT
+	test	rax, rax
+	jz	short \notFound@PLT
 
 	ret
 
 .LtaggedPointer_\name:
-	movq	objc_taggedPointerSecret@GOTPCREL(%rip), %rax
-	xorq	(%rax), %rdi
-	andb	$0xE, %dil
-	movzbl	%dil, %r8d
-
-	movq	objc_taggedPointerClasses@GOTPCREL(%rip), %rax
-	movq	(%rax,%r8,4), %r8
-	movq	64(%r8), %r8
-
-	jmp	.Lmain_\name
+	mov	rax, [rip + objc_taggedPointerSecret@GOTPCREL]
+	xor	rdi, [rax]
+	and	dil, 0xE
+	movzx	r8d, dil
+
+	mov	rax, [rip + objc_taggedPointerClasses@GOTPCREL]
+	mov	r8, [rax + 4 * r8]
+	mov	r8, [r8 + 64]
+
+	jmp	short .Lmain_\name
 .type \name, %function
 .size \name, .-\name
 .endm
 
 .macro GENERATE_LOOKUP_SUPER name lookup
 \name:
-	movq	%rdi, %r8
-	movq	(%rdi), %rdi
-	testq	%rdi, %rdi
-	jz	returnNilMethod
-
-	movq	8(%r8), %r8
-	movq	64(%r8), %r8
-	jmp	.Lmain_\lookup
+	mov	r8, rdi
+	mov	rdi, [rdi]
+	test	rdi, rdi
+	jz	short returnNilMethod
+
+	mov	r8, [r8 + 8]
+	mov	r8, [r8 + 64]
+	jmp	short .Lmain_\lookup
 .type \name, %function
 .size \name, .-\name
 .endm
 
 GENERATE_LOOKUP objc_msg_lookup objc_methodNotFound
@@ -84,15 +86,15 @@
 GENERATE_LOOKUP objc_msg_lookup_stret objc_methodNotFound_stret
 GENERATE_LOOKUP_SUPER objc_msg_lookup_super objc_msg_lookup
 GENERATE_LOOKUP_SUPER objc_msg_lookup_super_stret objc_msg_lookup_stret
 
 returnNilMethod:
-	leaq	nilMethod(%rip), %rax
+	lea	rax, [rip + nilMethod]
 	ret
 
 nilMethod:
-	xorq	%rax, %rax
+	xor	rax, rax
 	ret
 
 #if defined(OF_LINUX) || defined(OF_HAIKU) || defined(OF_HURD)
 .section .note.GNU-stack, "", %progbits
 #endif