/*
* Copyright (c) 2008-2023 Jonathan Schleifer <js@nil.im>
*
* All rights reserved.
*
* This file is part of ObjFW. It may be distributed under the terms of the
* Q Public License 1.0, which can be found in the file LICENSE.QPL included in
* the packaging of this file.
*
* Alternatively, it may be distributed under the terms of the GNU General
* Public License, either version 2 or 3, which can be found in the file
* LICENSE.GPLv2 or LICENSE.GPLv3 respectively included in the packaging of this
* file.
*/
#include "config.h"
#include "platform.h"
.globl OFForward
.globl OFForward_stret
.section .text
OFForward:
pushl %ebp
movl %esp, %ebp
pushl %ebx
subl $20, %esp
call getEIP
addl $_GLOBAL_OFFSET_TABLE_, %ebx
movl 8(%ebp), %eax
movl %eax, (%esp)
call object_getClass@PLT
movl %eax, (%esp)
leal sel_forwardingTargetForSelector_@GOTOFF(%ebx), %eax
movl %eax, 4(%esp)
call class_respondsToSelector@PLT
testl %eax, %eax
jz 0f
movl 8(%ebp), %eax
movl %eax, (%esp)
leal sel_forwardingTargetForSelector_@GOTOFF(%ebx), %eax
movl %eax, 4(%esp)
call objc_msg_lookup@PLT
movl 8(%ebp), %edx
movl %edx, (%esp)
leal sel_forwardingTargetForSelector_@GOTOFF(%ebx), %edx
movl %edx, 4(%esp)
movl 12(%ebp), %edx
movl %edx, 8(%esp)
call *%eax
testl %eax, %eax
jz 0f
cmpl 8(%ebp), %eax
je 0f
movl %eax, 8(%ebp)
movl %eax, (%esp)
movl 12(%ebp), %eax
movl %eax, 4(%esp)
call objc_msg_lookup@PLT
addl $20, %esp
popl %ebx
popl %ebp
jmp *%eax
0:
movl OFMethodNotFound@GOT(%ebx), %eax
addl $20, %esp
popl %ebx
popl %ebp
jmp *%eax
.type OFForward, %function
.size OFForward, .-OFForward
OFForward_stret:
pushl %ebp
movl %esp, %ebp
pushl %ebx
subl $20, %esp
call getEIP
addl $_GLOBAL_OFFSET_TABLE_, %ebx
movl 12(%ebp), %eax
movl %eax, (%esp)
call object_getClass@PLT
movl %eax, (%esp)
leal sel_forwardingTargetForSelector_@GOTOFF(%ebx), %eax
movl %eax, 4(%esp)
call class_respondsToSelector@PLT
testl %eax, %eax
jz 0f
movl 12(%ebp), %eax
movl %eax, (%esp)
leal sel_forwardingTargetForSelector_@GOTOFF(%ebx), %eax
movl %eax, 4(%esp)
call objc_msg_lookup@PLT
movl 12(%ebp), %edx
movl %edx, (%esp)
leal sel_forwardingTargetForSelector_@GOTOFF(%ebx), %edx
movl %edx, 4(%esp)
movl 16(%ebp), %edx
movl %edx, 8(%esp)
call *%eax
testl %eax, %eax
jz 0f
cmpl 12(%ebp), %eax
je 0f
movl %eax, 12(%ebp)
movl %eax, (%esp)
movl 16(%ebp), %eax
movl %eax, 4(%esp)
call objc_msg_lookup_stret@PLT
addl $20, %esp
popl %ebx
popl %ebp
jmp *%eax
0:
movl OFMethodNotFound_stret@GOT(%ebx), %eax
addl $20, %esp
popl %ebx
popl %ebp
jmp *%eax
.type OFForward_stret, %function
.size OFForward_stret, .-OFForward_stret
init:
pushl %ebp
movl %esp, %ebp
pushl %ebx
subl $4, %esp
call getEIP
addl $_GLOBAL_OFFSET_TABLE_, %ebx
leal module@GOTOFF(%ebx), %eax
movl %eax, (%esp)
call __objc_exec_class@PLT
addl $4, %esp
popl %ebx
popl %ebp
ret
getEIP:
movl (%esp), %ebx
ret
#ifdef OF_SOLARIS
.section .init_array, "aw"
#else
.section .ctors, "aw", %progbits
#endif
.long init
.section .rodata
str_forwardingTargetForSelector_:
.asciz "forwardingTargetForSelector:"
.section .data
sel_forwardingTargetForSelector_:
.long str_forwardingTargetForSelector_, 0
.long 0, 0
symtab:
.long 0, sel_forwardingTargetForSelector_
.short 0, 0
.long 0
.long 0
module:
.long 8, 16, 0, symtab
#if defined(OF_LINUX) || defined(OF_HAIKU) || defined(OF_HURD)
.section .note.GNU-stack, "", %progbits
#endif